tooltips.swf, tooltips.fla (source).

smartscale.swf, smartscale.fla (source).

ToolTips plugin

ToolTips plugin is very simple: add alt tag to all hotspots you want to see the tooltips:

<spot id="left" alt="move left" static="1" align="BC" salign="BC" staticX="-225.5" staticY="-5" url="images/black_l.png" /> <spot id="right" alt="move right" static="1" align="BC" salign="BC" staticX="-150.5" staticY="-5" url="images/black_r.png" />
ToolTips plugin searches and shows alt tags using nice yellow box. That’s all, nice and easy.

So alt tag is a part of Hotspots code, you can change it dynamically, I’m using in example above:

onEnterFullscreen="full.alt=exit fullscreen" onExitFullscreen="full.alt=enter ullscreen"
This code is changing the tip for fullscreen button depends on the stage state.

SmartScale plugin

SmartScale works with hotspots too. It searches tags with smartStale=”1″ attribute and changes the scale and positions of navigation buttons depends on the screen width (good for flexible windows). This functionality cannot be done using Hotspots script so it doesn’t support conditions. But some Actionscript in the plugin did the trick.

Linear scaling looks a little inaccurate (too big buttons if your screen is really wide), so I added an additional scale mode in SmartScale plugin: it reduces the size of buttons only if the width is less than 800. It prevents missing buttons if your screen is small, but it do not scale the buttons more than 100%. Check the second example.

This second scale mode is switching on by additional parameter in XML:

<smartscale> mode=reduce </smartscale>

Both examples are good if you want to create your own plugin to work with Flash Panorama Player hotspots.

lensFlare.swf, lensFlare.fla (source).

Typical usage

Paste this code to your Hotspots plugin XML:

<spot id="lens" url="files/lensFlare.swf" pan="-44" tilt="45" align="LT" buttonMode="0" blendmode="lighten" scaleable="0" radiance="0.3" />
(blendMode=”lighten” makes it more natural in my opinion, you can remove it; radiance=”0.3″ defines the power of “blinding effect” when the flare is on the screen, use values from 0 till 2).
Use Editor plugin to superpose the lens flare spot to the source of light (sun, for example) on the panorama image.

Custom glares

If you have Adobe Flash CS3, you are able to create your own lens flare plugins. Open the source of the plugin and edit the graphic elements. I made a simple flare effect with rounded barely visible glares. You can add any shaped glares in any color. Good glare effect can animate the scene a lot. But be careful with number of glares, too many glares with various alpha and blur effects require additional processor time and can slow down your panorama.

Custom code

If you have Actionscript 3 knowledge, you are able to change everything in the source. This source is a good template as well if you want to create some plugin with interactive elements on the panorama image.

I remind that there are no differences between various types of panorama images (QTVR files, cube faces, spherical or cylindrical images) inside the player. You can use any player extension with any panorama type. This is another example (cylindrical QTVR file with lens flare effect).

There is no restrictions for open source plugins. You can change, rewrite, distribute and use them as you wish. You can write your own plugins based on open source code and you can sell your work and your plugins to other Flash Panorama Player’s customers (if you can implement something worthwhile of course ).

I think the community of Flash Panorama Player now is big and smart enough and I’m not going to implement all possible features myself always. You can do some too. Meanwhile I’m going to focus on API documentation and the engine improvements.

If you are customer of Flash Panorama Player but you are still not on this forum (http://flashpanoramas.com/forum/), please, register. You can find there some people who know about the player more than me! It’s true, I saw some questions on the forum and I have no idea how to answer them, but some other users answer them without a problem. I got some new info about my player usage at that time. It’s amazing!

Thanks for all, guys.
Sincerely,
Denis.

Download: SWFParser.air (Adobe AIR is required to run this software).

Working on GUI for Flash Panorama Player I noticed there is no appropriate library for SWF authoring. I tried free libraries like sswf and swf tools, also I checked commercial ActiveX products for SWF authoring/transformation like SWF Generator and SWF Scout. They are not bad for simple manipulations on old versions of SWF files, but all of them have big problems with 9th version of Flash format, also practically they are not working with SWF library items (only with scene objects). What a pity…

Now there is a question: why not using Actionscript for SWF manipulations? I can’t find any info about this except some unanswered questions on different Flash forums. This strange because Actionscript 3 has all capabilities to work with SWF: ByteArray, zlib library, png/jpg decoders and loadBytes() function to convert the result into DisplayObject and test it on the fly. This gives a possibility to create online tools for SWF transformation. For example: there is a big problem to load and control Actionscript 1-2 files inside Actionscript 3 application (no direct communications between AVM1 and AVM2). SWF library would allow disjointing SWF resources (images, vector shapes, movieclips and so on) and control them separately. Another way: just insert some communication object like SWF Adapter to AS2 application on the fly (one additional SWF tag) and convert it into AVM1 movie.

Together with new Adobe AIR technology this will provide a powerful platform for offline SWF authoring (multiplatform: single application for Windows and Mac, and for Linux a little later).

So, SWF parser is a test of technology. Features:

• Parse SWF format (all versions).
• See SWF file info (version, size, FPS) and tags structure.
• Extract all bitmap images.
• Type path to any local or internet SWF file.
• Drag any swf files to the application (one or more).
• Drag direct URL to SWF file from browser’s address bar.
• Drag extracted images to any folder to save them.
• No image quality reduction: jpeg files are saving as is, without recompression.
• It works for Windows and Mac.
• It’s only 17 kb the whole application.
• Free for use (and partially open source).

This is an example how to parse SWF file (I believe this will be useful if you want to continue this idea).
Place it to the first frame in Flash CS3 or insert it to your AS3 class.

/*
Simple SWF parser
Written by Denis V. Chumakov 
http://flashpanoramas.com/blog/
Use this code without any restrictions.
*/

// log string
var parseLog:String;

// handlers for SWF tags
// for example: 
// handlers[6] = parseJPEG; 
// to set your handler for DefineBitsJPEG tag.
// you can find SWF file specifications in Google.
var handlers:Array = [];

// parse SWF file
function parseSWF(data:ByteArray) {
	parseLog = "";
	data.endian = Endian.LITTLE_ENDIAN;
	var format:String = data.readUTFBytes(3);
	var compressed:Boolean = format=="CWS";
	if (format=="FWS" || format=="CWS") {
		parseLog += "SWF version "+data.readByte();
		parseLog += ", size: "+data.readUnsignedInt();
	} else {
		parseLog += "Not a Flash file.";
		return;
	}
	data.readBytes(data);
	data.length -= 8;
	if (compressed) {
		data.uncompress();
	}
	data.position = 0;
	var frame:Array = readBox(data);
	parseLog += "\n";
	parseLog += "Width: "+Math.round((frame[1]-frame[0])/20);
	parseLog += ", height: "+Math.round((frame[3]-frame[2])/20);
	var fps_f:uint = data.readUnsignedByte();
	var fps_i:uint = data.readUnsignedByte();
	parseLog += "\n";
	parseLog += "FPS: "+(fps_i+fps_f/256);
	var count:uint = data.readUnsignedShort();
	parseLog += "\n";
	parseLog += "Total frames: "+count;
	parseLog += "\n";
	while (data.bytesAvailable) {
		readSWFTag(data);
	}
	trace(parseLog);
}

// read SWF tag and call handler if present
function readSWFTag(data:ByteArray) {
	var tag:uint = data.readUnsignedShort();
	var id:int = tag>>6;
	var size:int = tag&0x3F;
	if (size == 0x3F) {
		size = data.readUnsignedInt();
	}
	parseLog += "\n";
	parseLog += "Tag "+id;
	if (handlers[id]!=null) {
		var dump:ByteArray = new ByteArray();
		if (size!=0) {
			data.readBytes(dump,0,size);
		}
		handlers[id](tag, id, size, dump);
	} else {
		data.position += size;
	}
	parseLog += "\tsize: "+size;
}

// read compressed box format
function readBox(data:ByteArray):Array {
	var c:Array = [];
	var current:uint = data.readUnsignedByte();
	var size:uint = current>>3;
	var off:int = 3;
	for (var i:int=0; i<4; i+=1) {
		c[i] = current<<(32-off)>>(32-size);
		off -= size;
		while (off<0) {
			current = data.readUnsignedByte();
			c[i] |= off<-8?current<<(-off-8):current>>(-off-8);
			off += 8;
		}
	}
	return c;
}

var loader:URLLoader = new URLLoader();
loader.dataFormat = URLLoaderDataFormat.BINARY;
loader.addEventListener(Event.COMPLETE, loadComplete);
// load complete handler
function loadComplete(event:Event) {
	parseSWF(loader.data);
}
loader.load(new URLRequest("myfile.swf"));